<?xml version="1.0" encoding="windows-1251"?>
<!DOCTYPE xsl:stylesheet>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output xmlns="http://www.w3.org/TR/xhtml1/strict" doctype-public="-//W3C//DTD XHTML 1.0 Strict//EN"
encoding="Windows-1251" indent="yes" method="html" omit-xml-declaration="no" version="1.0" media-type="text/xml" />

<xsl:template match="/">
	<xsl:apply-templates select="shop"/>
</xsl:template>

<!-- Шаблон для магазина -->
<xsl:template match="/shop">
	<!-- Получаем ID родительской группы и записываем в переменную $parent_group_id -->
	<xsl:variable name="parent_group_id" select="@current_group_id"/>
	
	<!-- Если в находимся корне - выводим название информационной системы -->
	<xsl:if test="$parent_group_id=0">
		<h1><xsl:value-of disable-output-escaping="yes" select="name"/></h1>
	</xsl:if>
	
	<!-- Если в находимся в группе - выводим название группы -->
	<xsl:if test="$parent_group_id!=0">
		<h1><xsl:value-of disable-output-escaping="yes" select=".//group[@id=$parent_group_id]/name"/></h1>
	</xsl:if>
	
	<!-- Путь к группе -->
	<p><xsl:apply-templates select=".//group[@id=$parent_group_id]" mode="goup_path"/></p>

	<xsl:variable name="count">1</xsl:variable>

	<!-- Выводим группы магазина -->
	<table width="100%" cellspacing="0" cellpadding="0" border="0">
	<tr>
		<xsl:apply-templates select="//group[@parent=$parent_group_id]"/>
	</tr>
	</table>
	
	<xsl:if test="count(item) > 0">
		<form method="get" action="./">
		<p>
		<div style="background: #F5F5F7; padding: 7px;">
		Производитель&#xa0;
		<select name="producer_id">
			<option value="0">&#x2026;</option>
			<xsl:apply-templates select="producerslist/producer"/>
		</select>
		
		&#xa0;Продавец&#xa0;
		<select name="saller_id">
			<option value="0">&#x2026;</option>
			<xsl:apply-templates select="sallers/saller"/>
		</select>
		
		&#xa0;Цена от&#xa0;
		<input name="price_from" size="5" type="text">
			<xsl:if test="/shop/price_from != 0">
				<xsl:attribute name="value">
					<xsl:value-of disable-output-escaping="yes" select="/shop/price_from"/>
				</xsl:attribute>
			</xsl:if>	
		</input>
	
		&#xa0;до&#xa0;
		<input name="price_to" size="5" type="text">
			<xsl:if test="/shop/price_to != 0">
				<xsl:attribute name="value">
					<xsl:value-of disable-output-escaping="yes" select="/shop/price_to"/>
				</xsl:attribute>
			</xsl:if>	
		</input>
		&#xa0;Товаров на странице&#xa0;
		<select name="on_page">
			<option value="0">&#x2026;</option>
			<xsl:call-template name="for_on_page">
				<xsl:with-param name="i" select="10"/>
				<xsl:with-param name="n" select="50"/>
			</xsl:call-template>
		</select>
		&#xa0;<input name="apply_filter" value="Применить" type="submit" />
		
		<xsl:if test="count(properties_for_group/property) > 0">
		<p><b>Фильтр по дополнительным свойствам товара:</b></p>
			<table cellpadding="10px" cellspacing="0">
				<tr valign="top">
					<xsl:apply-templates select="properties_for_group/property"/>
				</tr>
			</table>
		</xsl:if>
		</div>
		</p>
		
		<!-- Таблица с элементами для сравнения -->
		<xsl:if test="count(/shop/compare_items/compare_item) > 0">
			<table cellpadding="5px" cellspacing="0">
				<tr>
					<td colspan=""><b>Сравниваемые элементы</b></td>
					<td><b>Убрать товар из сравнения</b></td>
				</tr>
				<xsl:apply-templates select="compare_items/compare_item"/>
				<tr>
					<td>
						<input name="apply_compare" value="Сравнить" type="button" onclick="javascript:location='{/shop/path}compare_items/';" />
					</td>
					<td align="right">
						<input name="delete_compare" value="Удалить" type="submit"/>
						<input name="delete_all_compare" value="Удалить все" type="submit" />
					</td>
				</tr>
			</table>
		</xsl:if>
		
		<!-- Определяем ссылку с параметрами фильтра -->
		<xsl:variable name="filter">
		<xsl:choose>
			<xsl:when test="/shop/apply_filter/node()">?action=apply_filter&amp;producer_id=<xsl:value-of select="/shop/producer_id"/>&amp;saller_id=<xsl:value-of select="/shop/saller_id"/>&amp;price_from=<xsl:value-of select="/shop/price_from"/>&amp;price_to=<xsl:value-of select="/shop/price_to"/>&amp;on_page=<xsl:value-of select="/shop/on_page"/>
				<xsl:if test="/shop/property_xml/node()">
					<!-- GET для доп. свойств -->
					<xsl:value-of select="/shop/property_xml"/>
				</xsl:if>
			</xsl:when>
			<xsl:otherwise></xsl:otherwise>
		</xsl:choose>
		</xsl:variable>
		<!-- Определяем первый символ вопрос или амперсанд -->
		<xsl:variable name="first_symbol">
		<xsl:choose>
			<xsl:when test="$filter != ''">&amp;</xsl:when>
			<xsl:otherwise>?</xsl:otherwise>
		</xsl:choose>
		</xsl:variable>
		
		<!-- Выводим товары магазина -->
		<table width="100%" cellspacing="5" cellpadding="2" border="0">
			<tr>
				<td height="25px" style="border-bottom: 1px solid #dadada;"><b>Изображение</b></td>
				<td style="border-bottom: 1px solid #dadada;">
					<b>Наименование</b>&#xa0;			
					<!-- Отображаем стрелки сортировки -->
					<xsl:choose>
						<xsl:when test="/shop/sort_by_field = 1">
							<xsl:choose>
								<!-- Стрелка вверх -->
								<xsl:when test="/shop/order_direction = 'ASC'">
									<img src="/hostcmsfiles/images/arrow_up.gif"/>&#xa0;
									<a href="{$filter}{$first_symbol}sort_by_field=1&amp;order_direction=2"><img src="/hostcmsfiles/images/arrow_down_gray.gif"/></a>
								</xsl:when>
								<!-- Стрелка вниз -->
								<xsl:otherwise>
									<a href="{$filter}{$first_symbol}sort_by_field=1&amp;order_direction=1"><img src="/hostcmsfiles/images/arrow_up_gray.gif"/></a>&#xa0;
									<img src="/hostcmsfiles/images/arrow_down.gif"/>
								</xsl:otherwise>
							</xsl:choose>	
						</xsl:when>
						<xsl:otherwise>
							<!-- Серые стрелки -->
							<xsl:value-of select="compare_item_name"/>
							<a href="{$filter}{$first_symbol}sort_by_field=1&amp;order_direction=1"><img src="/hostcmsfiles/images/arrow_up_gray.gif"/></a>&#xa0;
							<a href="{$filter}{$first_symbol}sort_by_field=1&amp;order_direction=2"><img src="/hostcmsfiles/images/arrow_down_gray.gif"/></a>
						</xsl:otherwise>
					</xsl:choose>
				</td>
				<td style="border-bottom: 1px solid #dadada;"><b>Описание</b></td>
				<td style="border-bottom: 1px solid #dadada;">
					<b>Цена</b>&#xa0;	
					<!-- Отображаем стрелки сортировки -->
					<xsl:choose>
						<xsl:when test="/shop/sort_by_field = 2">
							<xsl:choose>
								<!-- Стрелка вверх -->
								<xsl:when test="/shop/order_direction = 'ASC'">
									<img src="/hostcmsfiles/images/arrow_up.gif"/>&#xa0;
									<a href="{$filter}{$first_symbol}sort_by_field=2&amp;order_direction=2"><img src="/hostcmsfiles/images/arrow_down_gray.gif"/></a>
								</xsl:when>
								<!-- Стрелка вниз -->
								<xsl:otherwise>
									<a href="{$filter}{$first_symbol}sort_by_field=2&amp;order_direction=1"><img src="/hostcmsfiles/images/arrow_up_gray.gif"/></a>&#xa0;
									<img src="/hostcmsfiles/images/arrow_down.gif"/>
								</xsl:otherwise>
							</xsl:choose>	
						</xsl:when>
						<xsl:otherwise>
							<!-- Серые стрелки -->
							<xsl:value-of select="compare_item_name"/>
							<a href="{$filter}{$first_symbol}sort_by_field=2&amp;order_direction=1"><img src="/hostcmsfiles/images/arrow_up_gray.gif"/></a>&#xa0;
							<a href="{$filter}{$first_symbol}sort_by_field=2&amp;order_direction=2"><img src="/hostcmsfiles/images/arrow_down_gray.gif"/></a>
						</xsl:otherwise>
					</xsl:choose>
				</td>
				<td style="border-bottom: 1px solid #dadada;"><b>Сравнить</b></td>
			</tr>
			<xsl:apply-templates select="item"/>
		</table>
		<input name="add_compare" value="Добавить для сравнения" type="submit" />
		</form>
	</xsl:if>

	<!-- Строка ссылок на другие страницы каталога -->
	<p>
	<xsl:if test="count_items > 0 and items_on_page > 0">
		<xsl:call-template name="for">
			<xsl:with-param name="n" select="count_items div items_on_page"/>
			<xsl:with-param name="current_page" select="current_page"/>
		</xsl:call-template>
		<div style="clear: both"></div>
	</xsl:if>
	</p>
</xsl:template>

<!-- Шаблон для списка товаров для сравнения -->
<xsl:template match="compare_items/compare_item">
	<xsl:variable name="var_compare_id" select="." />
	<tr>
	<td>
		<a href="{/shop/path}{compare_item_fullpath}{compare_item_path}/">
		<xsl:value-of disable-output-escaping="yes" select="compare_item_name"/>
		</a>
	</td>
	<td>
		<input type="checkbox" name="del_compare_id_{compare_item_id}" id="id_del_compare_id_{compare_item_id}" />
		<label for="id_del_compare_id_{compare_item_id}">Да</label>
	</td>
	</tr>
</xsl:template>

<!-- Шаблон для фильтра производителей -->
<xsl:template match="producerslist/producer">
	<option value="{@id}">
	<xsl:if test="@id = /shop/producer_id">
		<xsl:attribute name="selected"> </xsl:attribute>
	</xsl:if>
	<xsl:value-of disable-output-escaping="yes" select="name"/>
	</option>
</xsl:template>

<!-- Шаблон для фильтра продавцов -->
<xsl:template match="sallers/saller">
	<option value="{@id}">
	<xsl:if test="@id = /shop/saller_id">
		<xsl:attribute name="selected"> </xsl:attribute>
	</xsl:if>
	<xsl:value-of select="sallers_name"/>
	</option>
</xsl:template>

<!-- Шаблон для фильра по дополнительным свойствам -->
<xsl:template match="properties_for_group/property">
	<td>
	<xsl:value-of disable-output-escaping="yes" select="property_name"/>&#xa0;
	<xsl:if test="property_show_kind = 1">
		<!-- Отображаем поле ввода -->
		<xsl:variable name="nodename">property_id_<xsl:value-of select="@id"/></xsl:variable>
		<br /><input type="text" name="property_id_{@id}">
			<xsl:if test="/shop/*[name()=$nodename] != ''">
				<xsl:attribute name="value">
				<xsl:value-of disable-output-escaping="yes" select="/shop/*[name()=$nodename]"/>
				</xsl:attribute>
			</xsl:if>
		</input>
	</xsl:if>
	<xsl:if test="property_show_kind = 2">
		<!-- Отображаем список -->
		<br /><select name="property_id_{@id}">
			 <option value="0">...</option> -->
			<xsl:apply-templates select="list_items/list_item"/>
		</select>
	</xsl:if>	
	<xsl:if test="property_show_kind = 3">
		<!-- Отображаем переключатели -->
		<br /><input type="radio" name="property_id_{@id}" value="0" id="id_prop_radio_{@id}_0"></input>
		<label for="id_prop_radio_{@id}_0">Любой вариант</label>
		<xsl:apply-templates select="list_items/list_item"/>
	</xsl:if>	
	<xsl:if test=" property_show_kind = 4">
		<!-- Отображаем флажки -->
		<xsl:apply-templates select="list_items/list_item"/>
	</xsl:if>	
	</td>
	<xsl:if test="position() mod 6 = 0">
		<xsl:text disable-output-escaping="yes">
			&lt;/tr&gt;
			&lt;tr valign="top"&gt;
		</xsl:text>
	</xsl:if>
</xsl:template>

<xsl:template match="list_items/list_item">
	<xsl:if test="../../property_show_kind = 2">
		<!-- Отображаем список -->
		<xsl:variable name="nodename">property_id_<xsl:value-of select="../../@id"/></xsl:variable>
		<option value="{@id}">		
			<xsl:if test="/shop/*[name()=$nodename] = @id">
				<xsl:attribute name="selected"> </xsl:attribute>
			</xsl:if>
			<xsl:value-of disable-output-escaping="yes" select="list_item_value"/>
		</option>
	</xsl:if>	
	<xsl:if test="../../property_show_kind = 3">
		<!-- Отображаем переключатели -->
		<xsl:variable name="nodename">property_id_<xsl:value-of select="../../@id"/></xsl:variable>
		<br /><input type="radio" name="property_id_{../../@id}" value="{@id}" id="id_property_id_{../../@id}_{@id}">
			<xsl:if test="/shop/*[name()=$nodename] = @id">
				<xsl:attribute name="checked"> </xsl:attribute>
			</xsl:if>
			<label for="id_property_id_{../../@id}_{@id}">
				<xsl:value-of disable-output-escaping="yes" select="list_item_value"/>
			</label>
		</input>
	</xsl:if>
	<xsl:if test="../../property_show_kind = 4">
		<!-- Отображаем флажки -->
		<xsl:variable name="nodename">property_id_<xsl:value-of select="../../@id"/>_item_id_<xsl:value-of select="@id"/></xsl:variable>
		<br /><input type="checkbox" name="property_id_{../../@id}_item_id_{@id}" id="id_property_id_{../../@id}_{@id}">
			<xsl:if test="/shop/*[name()=$nodename] = @id">
				<xsl:attribute name="checked"> </xsl:attribute>
			</xsl:if>
			<label for="id_property_id_{../../@id}_{@id}">
				<xsl:value-of disable-output-escaping="yes" select="list_item_value"/>
			</label>
		</input>
	</xsl:if>	
</xsl:template>

<!-- Цикл с шагом 10 для select'a количества элементов на страницу -->
<xsl:template name="for_on_page">
	<xsl:param name="i" select="0"/>
	<xsl:param name="n"/>

	<option value="{$i}">
		<xsl:if test="$i = /shop/on_page">
			<xsl:attribute name="selected"> </xsl:attribute>
		</xsl:if>
		<xsl:value-of select="$i"/>
	</option>
	
	<xsl:if test="$n > $i">	
		<!-- Рекурсивный вызов шаблона -->
		<xsl:call-template name="for_on_page">
			<xsl:with-param name="i" select="$i + 10"/>
			<xsl:with-param name="n" select="$n"/>
		</xsl:call-template>
	</xsl:if>
</xsl:template>
	
<!-- Шаблон для групп товара -->
<xsl:template match="group">
	<td valign="top" width="33%">
	<b><a href="{/shop/path}{fullpath}"><xsl:value-of disable-output-escaping="yes" select="name"/></a></b>
	
	<!-- Количество элементов в группе -->
	&#160;<span style="color: #aaaaaa">(<xsl:value-of disable-output-escaping="yes" select="count_all_items"/>)</span>
	
	
	<br/>
	<!-- Если есть изображение для группы - выводим его -->
	<xsl:if test="small_image != ''">
		<img src="{small_image}" align="left" style="border: 1px solid #000000" />
	</xsl:if>
	<!-- Выводим описание -->
	<xsl:value-of disable-output-escaping="yes" select="description"/>
	</td>
	
	<!-- На строку - не более 3-х пунктов, если уже 3 выведено - начинаем новую строку -->
	<xsl:if test="position() mod 3 = 0">
	<xsl:text disable-output-escaping="yes">
		&lt;/tr&gt;
		&lt;tr&gt;
	</xsl:text>
	</xsl:if>
</xsl:template>

<!-- Шаблон для товара -->
<xsl:template match="item">

	<!-- Определяем цвет фона -->
	<xsl:variable name="background_color">
		<xsl:choose>
			<xsl:when test="(position() + 1) mod 2 > 0">#f7f7f7</xsl:when>
			<xsl:otherwise>#ffffff</xsl:otherwise>
		</xsl:choose>
	</xsl:variable>
	
	<tr style="background-color: {$background_color}; padding: 5px;">
	<td>
		<!-- Изображение для товара, если есть -->
		<xsl:if test="small_image!=''">
			<a href="{/shop/path}{fullpath}{path}/"><img src="{small_image}" align="left" style="border: 1px solid #000000; margin: 0px 5px 5px 0px" /></a>
		</xsl:if>
	</td>
	<td width="25%">
		<!-- Название товара -->
		<a href="{/shop/path}{fullpath}{path}/"><xsl:value-of disable-output-escaping="yes" select="name"/></a>
	</td>	
	<td>		
		<!-- Описание товара -->
		<xsl:value-of disable-output-escaping="yes" select="description"/>
		<!-- Продавец -->
		<xsl:if test="saller!=0"><br /><br />
			<!-- Идентификатор текущего продавца -->
			<xsl:variable name="saller_id" select="saller" />
			<b>Продавец:&#xa0;</b><a href="{/shop/path}sallers/saller-{saller}/"><xsl:value-of select="/shop/sallers/saller[@id=$saller_id]/sallers_name"/></a>
		</xsl:if>
		<!-- Если указан вес товара -->
		<xsl:if test="weight != 0"><br />
			Вес товара: <xsl:value-of select="weight"/> <xsl:value-of select="weight_mesure"/> 
		</xsl:if>
		<!-- Скидки -->
		<xsl:if test="count(discount) > 0"><br /><br />
			Скидки: <xsl:apply-templates select="discount"/>
		</xsl:if>
		<!-- Модификации -->
		<xsl:if test="count(modifications/item) > 0"><br /><br />
			<b>Модификации:</b>
			<table cellspacing="0" cellpadding="2">
			<tr>
				<td style="border-bottom: 1px solid #dadada;">Название</td>
				<td style="border-bottom: 1px solid #dadada;">Цена</td>
			</tr>
			<xsl:apply-templates select="modifications/item"/>
			</table>
		</xsl:if>
	</td>
	<td width="100px">
		<!-- Ссылка на добавление в корзину -->
		<a href="/shop/cart/?action=add&amp;item_id={@id}"><img alt="В корзину" title="В корзину" src="/hostcmsfiles/images/cart.gif"/></a>&#xA0;
		<!-- Цена товара -->
		<strong>
			<xsl:choose>
				<xsl:when test="price != 0">
					<xsl:value-of disable-output-escaping="yes" select="price"/>&#xA0;
					<!-- Валюта товара -->
					<xsl:value-of disable-output-escaping="yes" select="currency"/>
				</xsl:when>
				<xsl:otherwise>договорная</xsl:otherwise>
			</xsl:choose>
		</strong>
		<!-- Если цена со скидкой - выводим ее -->
		<xsl:if test="price!=price_tax">
		<br/>
		<font color="gray">
			<strike>
				<xsl:value-of disable-output-escaping="yes" select="price_tax"/>&#xA0;<xsl:value-of disable-output-escaping="yes" select="currency"/>
			</strike>
		</font>
		</xsl:if>
	</td>	
	<td align="center">	
		<!-- Флажок сравнения -->
		<xsl:variable name="var_compare_id" select="@id" />
		<input type="checkbox" name="compare_id_{@id}" id="id_compare_id_{@id}">
		<xsl:if test="/shop/compare_items/compare_item[compare_item_id = $var_compare_id]/node()">
			<xsl:attribute name="checked"> </xsl:attribute>
			<xsl:attribute name="disabled"> </xsl:attribute>
		</xsl:if>
		</input>
	</td>
	</tr>

	<!-- На строку - не более 3-х пунктов, если уже 3 выведено - начинаем новую строку -->
	<!--
	<xsl:if test="position() mod 3 = 0">
	<xsl:text disable-output-escaping="yes">
		&lt;/tr&gt;
		&lt;tr&gt;
	</xsl:text>
	</xsl:if>
	-->	 
</xsl:template>

<!-- Шаблон для модификаций -->
<xsl:template match="modifications/item">
	<tr>
		<td>
			<!-- Название модификации -->
			<a href="{/shop/path}{fullpath}{path}/"><xsl:value-of disable-output-escaping="yes" select="name"/></a>
		</td>
		<td>
			<!-- Цена модификации -->
			<xsl:choose>
				<xsl:when test="price != 0">
					<xsl:value-of disable-output-escaping="yes" select="price"/>&#xA0;
					<!-- Валюта товара -->
					<xsl:value-of disable-output-escaping="yes" select="currency"/>
				</xsl:when>
				<xsl:otherwise>договорная</xsl:otherwise>
			</xsl:choose>	
		</td>
	</tr>
</xsl:template>

<!-- Шаблон для скидки -->
<xsl:template match="discount">
	<br/>
	<xsl:value-of disable-output-escaping="yes" select="name"/>&#xA0;
	<xsl:value-of disable-output-escaping="yes" select="value"/>%
</xsl:template>

<!-- ============================ -->
<!-- Цикл для вывода строк ссылок -->
<!-- ============================ -->
<xsl:template name="for">
	<xsl:param name="i" select="0"/>
	<xsl:param name="n"/>
	<xsl:param name="current_page"/>
	
	<xsl:if test="$n > $i and $n > 1">	
		<!-- Ставим ссылку на страницу-->
		<xsl:if test="$i != $current_page">
			
			<!-- Заносим в переменную $parent_group_id идентификатор текущей группы -->
			<xsl:variable name="parent_group_id" select="/shop/@current_group_id"/>
			
			<!-- Определяем группу для формирования адреса ссылки -->
			<xsl:variable name="group_link"><xsl:choose>
				<!-- Если группа не корневая (!=0) -->
				<xsl:when test="$parent_group_id != 0"><xsl:value-of select="/shop//group[@id=$parent_group_id]/fullpath"/></xsl:when>
				<!-- Иначе если нулевой уровень - просто ссылка на страницу со списком элементов -->
				<xsl:otherwise></xsl:otherwise>
			</xsl:choose></xsl:variable>
			
			<!-- Определяем адрес ссылки -->
			<xsl:variable name="number_link"><xsl:choose>
				<!-- Если не нулевой уровень -->
				<xsl:when test="$i != 0">page-<xsl:value-of select="$i+1"/>/</xsl:when>
				<!-- Иначе если нулевой уровень - просто ссылка на страницу со списком элементов -->
				<xsl:otherwise></xsl:otherwise>
			</xsl:choose></xsl:variable>

			<!-- Передаем фильтр -->
			<xsl:variable name="filter">
			<xsl:choose>
			<xsl:when test="/shop/apply_filter/node()">?action=apply_filter&amp;producer_id=<xsl:value-of select="/shop/producer_id"/>&amp;saller_id=<xsl:value-of select="/shop/saller_id"/>&amp;price_from=<xsl:value-of select="/shop/price_from"/>&amp;price_to=<xsl:value-of select="/shop/price_to"/>&amp;on_page=<xsl:value-of select="/shop/on_page"/>
				<xsl:if test="/shop/property_xml/node()">
					<!-- GET для доп. свойств -->
					<xsl:value-of select="/shop/property_xml"/>
				</xsl:if>
			</xsl:when>
			<xsl:otherwise></xsl:otherwise>
			</xsl:choose>
			</xsl:variable>
			
			<!-- Определяем первый символ вопрос или амперсанд -->
			<xsl:variable name="first_symbol">
			<xsl:choose>
				<xsl:when test="$filter != ''">&amp;</xsl:when>
				<xsl:otherwise>?</xsl:otherwise>
			</xsl:choose>
			</xsl:variable>
			
			<!-- Данные для стрелок сортировки -->
			<xsl:variable name="arrows">
			<xsl:choose>
				<xsl:when test="(/shop/sort_by_field = 1) or (/shop/sort_by_field = 2)">
					<xsl:choose>
						<!-- Стрелка вверх -->
						<xsl:when test="/shop/order_direction = 'ASC'"><xsl:value-of select="$first_symbol"/>sort_by_field=<xsl:value-of select="/shop/sort_by_field"/>&amp;order_direction=1</xsl:when>
						<!-- Стрелка вниз -->
						<xsl:otherwise><xsl:value-of select="$first_symbol"/>sort_by_field=<xsl:value-of select="/shop/sort_by_field"/>&amp;order_direction=2</xsl:otherwise>
					</xsl:choose>	
				</xsl:when>
				<xsl:otherwise></xsl:otherwise>
			</xsl:choose>
			</xsl:variable>
			<a href="{/shop/path}{$group_link}{$number_link}{$filter}{$arrows}" class="page_link"><xsl:value-of select="$i+1"/></a>
		</xsl:if>

		<!-- Не ставим ссылку на страницу-->
		<xsl:if test="$i = $current_page">
			<span class="current"><xsl:value-of select="$i+1"/></span>
		</xsl:if>

		<!-- Рекурсивный вызов шаблона. НЕОБХОДИМО ПЕРЕДАВАТЬ ВСЕ НЕОБХОДИМЫЕ ПАРАМЕТРЫ! -->
		<xsl:call-template name="for">
			<xsl:with-param name="i" select="$i + 1"/>
			<xsl:with-param name="n" select="$n"/>
			<xsl:with-param name="current_page" select="$current_page"/>
		</xsl:call-template>

	</xsl:if>
</xsl:template>

<!-- ======================================================== -->
<!-- Шаблон выводит рекурсивно ссылки на группы инф. элемента -->
<!-- ======================================================== -->

<xsl:template match="group" mode="goup_path">
	<xsl:param name="parent_id" select="@parent"/>

	<!-- Получаем ID родительской группы и записываем в переменную $parent_group_id -->
	<xsl:param name="parent_group_id" select="/shop/@current_group_id"/>

	<xsl:apply-templates select="//group[@id=$parent_id]" mode="goup_path"/>

	<xsl:if test="@parent=0">
		<a href="{/shop/path}"><xsl:value-of disable-output-escaping="yes" select="/shop/name"/></a>
	</xsl:if>

	<img src="/hostcmsfiles/images/arrow_path.gif" class="arrow_path"/>

	<!-- ============================================================================================== -->
	<!-- Если ID группы, для которой выводим список элементов, равен ID текущей группы - выводим жирным -->
	<!-- ============================================================================================== -->
	<xsl:if test="$parent_group_id=@id">
		<a href="{/shop/path}{fullpath}"><b><xsl:value-of disable-output-escaping="yes" select="name"/></b></a>
	</xsl:if>

	<!-- ============================ -->
	<!-- Иначе выводим обычную ссылку -->
	<!-- ============================ -->
	<xsl:if test="$parent_group_id!=@id">
		<a href="{/shop/path}{fullpath}"><xsl:value-of disable-output-escaping="yes" select="name"/></a>
	</xsl:if>

</xsl:template>

</xsl:stylesheet>