HostCMS → Форум → Общие вопросы по системе управления сайтом HostCMS v. 5 → XSL шаблон вывода галереи

XSL шаблон вывода галереи
22 декабря 2010 г.
#
XSL шаблон вывода галереи
Здравствуйте!

Очень нужна помощь в создании xsl-шаблона.

У элементов ИС, которые выводятся в галерею есть доп. свойство - флажок, "Показывать в галерее" (show_element).
Элементы выводятся в таблицу (за основу взят стандартный шаблон Фотогалерея/СписокКартинок).
Проблема в том, что если флажок не установлен и элемент не выводится, он всё равно защитывается (например, если установлено показывать 3 элемента в строке, а первый элемент не отмечен флажком, то в строке будет только 2 элемента).
Как изменить шаблон, чтобы НЕ отмеченные флажком show_element элементы не учитывались функцией position() (я думаю дело в ней) при выводе?

Код:

Здравствуйте!

Очень нужна помощь в создании xsl-шаблона.

У элементов ИС, которые выводятся в галерею есть доп. свойство - флажок, "Показывать в галерее" (show_element).
Элементы выводятся в таблицу (за основу взят стандартный шаблон Фотогалерея/СписокКартинок).
Проблема в том, что если флажок не установлен и элемент не выводится, он всё равно защитывается (например, если установлено показывать 3 элемента в строке, а первый элемент не отмечен флажком, то в строке будет только 2 элемента).
Как изменить шаблон, чтобы отмеченные флажком show_element не учитывались функцией position() (я думаю дело в ней) при выводе?

Код:
[code]
<?xml version="1.0" encoding="windows-1251"?>
<!DOCTYPE xsl:stylesheet>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output xmlns="http://www.w3.org/TR/xhtml1/strict" doctype-public="-//W3C//DTD XHTML 1.0 Strict//EN" encoding="Windows-1251" indent="yes" method="html" omit-xml-declaration="no" version="1.0" media-type="text/xml"/>

<!-- СписокКартинок -->

<xsl:template match="/">
  <xsl:apply-templates select="/document"/>
</xsl:template>

<xsl:template match="/document">

  <!-- Получаем ID родительской группы и записываем в переменную $parent_group_id -->
  <xsl:variable name="parent_group_id" select="blocks/parent_group_id"/>

  <!-- Если в находимся корне - выводим название информационной системы -->
  <xsl:if test="blocks/parent_group_id = 0">
   <h1>
    <xsl:value-of disable-output-escaping="yes" select="blocks/name"/>
   </h1>

   <!-- Описание выводится при отсутствии фильтрации по тэгам -->
   <xsl:if test="count(blocks/tags/tag) = 0">
    <xsl:value-of disable-output-escaping="yes" select="blocks/description"/>
   </xsl:if>
  </xsl:if>

  <!-- Если в находимся в группе - выводим название группы -->
  <xsl:if test="blocks/parent_group_id != 0">
   <h1>
    <xsl:value-of disable-output-escaping="yes" select=".//group[@id=$parent_group_id]/name"/>
   </h1>

   <!-- Описание выводим только на первой странице -->
   <xsl:if test="blocks/items/current_page = 0">
    <xsl:value-of disable-output-escaping="yes" select=".//group[@id=$parent_group_id]/description"/>
   </xsl:if>
  </xsl:if>

  <!-- Обработка выбранных тэгов -->
  <xsl:if test="count(blocks/selected_tags/tag) = 1">
  <h2>Метка &#x97; <strong><xsl:value-of select="blocks/selected_tags/tag/tag_name"/></strong>.</h2>
  </xsl:if>

  <!-- Отображение подгрупп данной группы, только если подгруппы есть и не идет фильтра по меткам -->
  <xsl:if test="count(blocks/selected_tags/tag) = 0 and count(.//group[@parent_id=$parent_group_id]) &gt; 0">
   <xsl:apply-templates select=".//group[@parent_id=$parent_group_id]" mode="groups"/>
  </xsl:if>

  <xsl:if test="count(//blocks/items/item[item_status=1]) > 0">
   <!-- Число элементов в строку -->
   <xsl:variable name="items_in_line" select="3"/>
   <!-- jQuery lightbox -->
   <div id="gallery" align="center">
  <table border="0" cellspacing="20" cellpadding="0">
    <xsl:call-template name="items">
     <xsl:with-param name="items_in_line" select="$items_in_line"/>
     <xsl:with-param name="current_position" select="0"/>
    </xsl:call-template>
  </table>
   </div>
  </xsl:if>

  <!-- Строка ссылок на другие страницы информационной системы -->
  <xsl:if test="ОтображатьСсылкиНаСледующиеСтраницы=1">
   <p class="pages_nav">
    <!-- Ссылка, для которой дописываются суффиксы page-XX/ -->
    <xsl:variable name="link">
     <xsl:value-of select="/document/blocks/url"/>
     <xsl:if test="$parent_group_id != 0">
      <xsl:value-of select="/document/blocks//group[@id = $parent_group_id]/fullpath"/>
     </xsl:if>
    </xsl:variable>

    <xsl:call-template name="for">
     <xsl:with-param name="link" select="$link"/>
     <xsl:with-param name="items_on_page" select="blocks/items/items_on_page"/>
     <xsl:with-param name="current_page" select="blocks/items/current_page"/>
     <xsl:with-param name="count_items" select="blocks/items/count_items"/>
     <xsl:with-param name="visible_pages">999</xsl:with-param>
    </xsl:call-template>
   </p>
  </xsl:if>

  <div style="clear: both"></div>

  <!-- Rss -->
  <!--<div class="rss_4_ie"></div>
  <a href="{blocks/url}rss/">
   <img src="/images/rss/rss_2.0.png" style="filter: alpha(opacity=0); margin: 0px 0px -4px 0px"/>
  </a>
  <a href="{blocks/url}rss/">RSS</a>-->

  <xsl:if test="ОтображатьСсылкуНаАрхив = 1">
   <div class="archives_4_ie"></div>
   <a href="{blocks/url}">
    <img src="/images/archives.png" style="filter: alpha(opacity=0); margin: 0px 0px -4px 0px"/>
   </a>
   <a href="{blocks/url}">Архив "<xsl:value-of disable-output-escaping="yes" select="blocks/name"/>"</a>
  </xsl:if>
</xsl:template>

<!-- Шаблон выводит рекурсивно ссылки на группы инф. элемента -->
<xsl:template match="group" mode="goup_path">
  <xsl:variable name="parent_id" select="@parent_id"/>

  <xsl:apply-templates select="//group[@id=$parent_id]" mode="goup_path"/>

  <xsl:if test="@parent_id=0">
   <a href="{/document/blocks/url}">
    <xsl:value-of disable-output-escaping="yes" select="/document/blocks/name"/>
   </a>
  </xsl:if>

  <span class="path_arrow">&#x2192;</span>

  <a href="{/document/blocks/url}{fullpath}">
   <xsl:value-of disable-output-escaping="yes" select="name"/>
  </a>
</xsl:template>

<!-- Шаблон выводит ссылки подгруппы информационного элемента -->
<xsl:template match="group" mode="groups">
  <div class="group_gallery">

   <a href="{/document/blocks/url}{fullpath}">
    <b>
     <xsl:value-of disable-output-escaping="yes" select="name"/>
    </b>
</a>&#xA0;<span style="color: #b7af9c">(<xsl:value-of select="count_all_items"/>)</span><xsl:value-of disable-output-escaping="yes" select="description"/></div>

</xsl:template>

<xsl:template name="items">
  <xsl:param name="items_in_line"/>
  <xsl:param name="current_position"/>
   <tr align="center" valign="top">
    <xsl:for-each select="//blocks/items/item[item_status=1]">
   
   
   <!-- Проверяем значение флажка -->
   

    <xsl:if test="item_propertys/item_property[@xml_name='show_element']/value = 1 or not (item_propertys/item_property[@xml_name='show_element']/value)">
   
     <xsl:if test="position() > $current_position and ($current_position + $items_in_line) >= position()">
      <td>
       <xsl:if test="item_small_image!=''">
        <!-- Проверяем задан ли путь к файлу большого изображения -->
        <xsl:if test="item_image!=''">
         <a href="{item_image}" target="_blank" title="Увеличить">
          <img src="{item_small_image}" title="{item_name}" alt="{item_name}" />
          <p><xsl:value-of disable-output-escaping="yes" select="item_name"/></p>
         </a>
        </xsl:if>
        <xsl:if test="item_image = ''">
         <img src="{item_small_image}" title="{item_name}" alt="{item_name}" />
         <p><xsl:value-of disable-output-escaping="yes" select="item_name"/></p>
        </xsl:if>
       </xsl:if>
      </td>
     </xsl:if>
   
    </xsl:if>
    </xsl:for-each>
   </tr>
  <xsl:if test="count(//blocks/items/item[item_status=1]) > ($current_position + $items_in_line)">
   <xsl:call-template name="items">
    <xsl:with-param name="items_in_line" select="$items_in_line"/>
    <xsl:with-param name="current_position" select="$current_position + $items_in_line"/>
   </xsl:call-template>
  </xsl:if>
</xsl:template>

<!-- /// Метки для информационного элемента /// -->
<xsl:template match="tags/tag">
  <a href="{/document/blocks/url}tag/{tag_path_name}/" class="tag">
   <xsl:value-of select="tag_name"/>
  </a>
<xsl:if test="position() != last()">,</xsl:if>&#xA0;</xsl:template>

<!-- Цикл для вывода строк ссылок -->
<xsl:template name="for">
  <xsl:param name="i" select="0"/>
  <xsl:param name="prefix">page</xsl:param>
  <xsl:param name="link"/>
  <xsl:param name="items_on_page"/>
  <xsl:param name="current_page"/>
  <xsl:param name="count_items"/>
  <xsl:param name="visible_pages"/>

  <xsl:variable name="n" select="$count_items div $items_on_page"/>

  <!-- Заносим в переменную $parent_group_id идентификатор текущей группы -->
  <xsl:variable name="parent_group_id" select="/document/blocks/parent_group_id"/>


  <!-- Считаем количество выводимых ссылок перед текущим элементом -->
  <xsl:variable name="pre_count_page">
   <xsl:choose>
    <xsl:when test="$current_page &gt; ($n - (round($visible_pages div 2) - 1))">
     <xsl:value-of select="$visible_pages - ($n - $current_page)"/>
    </xsl:when>
    <xsl:otherwise>
     <xsl:value-of select="round($visible_pages div 2) - 1"/>
    </xsl:otherwise>
   </xsl:choose>
  </xsl:variable>

  <!-- Считаем количество выводимых ссылок после текущего элемента -->
  <xsl:variable name="post_count_page">
   <xsl:choose>
    <xsl:when test="0 &gt; $current_page - (round($visible_pages div 2) - 1)">
     <xsl:value-of select="$visible_pages - $current_page - 1"/>
    </xsl:when>
    <xsl:otherwise>
     <xsl:choose>
      <xsl:when test="round($visible_pages div 2) = ($visible_pages div 2)">
       <xsl:value-of select="$visible_pages div 2"/>
      </xsl:when>
      <xsl:otherwise>
       <xsl:value-of select="round($visible_pages div 2) - 1"/>
      </xsl:otherwise>
     </xsl:choose>
    </xsl:otherwise>
   </xsl:choose>
  </xsl:variable>

  <xsl:if test="($count_items > $items_on_page) and $i = 0">
   Страница
  </xsl:if>

  <xsl:if test="$count_items &gt; $items_on_page and $n &gt; $i">
   <!-- Определяем адрес тэга -->
   <xsl:variable name="tag_link">
    <xsl:choose>
     <!-- Если не нулевой уровень -->
     <xsl:when test="count(/document/blocks/selected_tags/tag) != 0">tag/<xsl:value-of select="/document/blocks/selected_tags/tag/tag_path_name"/>/</xsl:when>
     <!-- Иначе если нулевой уровень - просто ссылка на страницу со списком элементов -->
     <xsl:otherwise></xsl:otherwise>
    </xsl:choose>
   </xsl:variable>

   <!-- Определяем адрес ссылки -->
   <xsl:variable name="number_link">
    <xsl:choose>
     <!-- Если не нулевой уровень -->
    <xsl:when test="$i != 0">
      <xsl:value-of select="$prefix"/>-<xsl:value-of select="$i + 1"/>/</xsl:when>
     <!-- Иначе если нулевой уровень - просто ссылка на страницу со списком элементов -->
     <xsl:otherwise></xsl:otherwise>
    </xsl:choose>
   </xsl:variable>

   <!-- Ставим ссылку на страницу-->
   <xsl:if test="$i != $current_page">
    <!-- Выводим ссылку на первую страницу -->
    <xsl:if test="$current_page - $pre_count_page &gt; 0 and $i = 0">
     <a href="{$link}" class="page_link" style="text-decoration: none;">&#x2190;</a>
    </xsl:if>

    <xsl:choose>
     <xsl:when test="$i &gt;= ($current_page - $pre_count_page) and ($current_page + $post_count_page) &gt;= $i">
      <!-- Выводим ссылки на видимые страницы -->
      <a href="{$link}{$tag_link}{$number_link}" class="page_link">
       <xsl:value-of select="$i + 1"/>
      </a>
     </xsl:when>
     <xsl:otherwise></xsl:otherwise>
    </xsl:choose>

    <!-- Выводим ссылку на последнюю страницу -->
    <xsl:if test="$i+1 &gt;= $n and $n &gt; ($current_page + 1 + $post_count_page)">
     <xsl:choose>
      <xsl:when test="$n &gt; round($n)">
       <!-- Выводим ссылку на последнюю страницу -->
       <a href="{$link}{$prefix}-{round($n+1)}/" class="page_link" style="text-decoration: none;">&#x2192;</a>
      </xsl:when>
      <xsl:otherwise>
       <a href="{$link}{$prefix}-{round($n)}/" class="page_link" style="text-decoration: none;">&#x2192;</a>
      </xsl:otherwise>
     </xsl:choose>
    </xsl:if>
   </xsl:if>

   <!-- Ссылка на следующую страницу для Ctrl + вправо -->
   <xsl:if test="($n - 1) &gt; $current_page and $i = $current_page">
    <a href="{$link}{$tag_link}page-{$current_page+2}/" id="id_next"></a>
   </xsl:if>

   <!-- Не ставим ссылку на страницу-->
   <xsl:if test="$i = $current_page">
    <span class="current">
     <xsl:value-of select="$i+1"/>
    </span>
   </xsl:if>

   <!-- Рекурсивный вызов шаблона. НЕОБХОДИМО ПЕРЕДАВАТЬ ВСЕ НЕОБХОДИМЫЕ ПАРАМЕТРЫ! -->
   <xsl:call-template name="for">
    <xsl:with-param name="i" select="$i + 1"/>
    <xsl:with-param name="prefix" select="$prefix"/>
    <xsl:with-param name="link" select="$link"/>
    <xsl:with-param name="items_on_page" select="$items_on_page"/>
    <xsl:with-param name="current_page" select="$current_page"/>
    <xsl:with-param name="count_items" select="$count_items"/>
    <xsl:with-param name="visible_pages" select="$visible_pages"/>
   </xsl:call-template>
  </xsl:if>
</xsl:template>

<!-- Склонение после числительных -->
<xsl:template name="declension">

  <xsl:param name="number" select="number"/>

  <!-- Именительный падеж -->
  <xsl:variable name="nominative">
   <xsl:text>комментарий</xsl:text>
  </xsl:variable>

  <!-- Родительный падеж, единственное число -->
  <xsl:variable name="genitive_singular">
   <xsl:text>комментария</xsl:text>
  </xsl:variable>


  <xsl:variable name="genitive_plural">
   <xsl:text>комментариев</xsl:text>
  </xsl:variable>

  <xsl:variable name="last_digit">
   <xsl:value-of select="$number mod 10"/>
  </xsl:variable>

  <xsl:variable name="last_two_digits">
   <xsl:value-of select="$number mod 100"/>
  </xsl:variable>

  <xsl:choose>
   <xsl:when test="$last_digit = 1 and $last_two_digits != 11">
    <xsl:value-of select="$nominative"/>
   </xsl:when>
   <xsl:when test="$last_digit = 2 and $last_two_digits != 12    or $last_digit = 3 and $last_two_digits != 13    or $last_digit = 4 and $last_two_digits != 14">
    <xsl:value-of select="$genitive_singular"/>
   </xsl:when>
   <xsl:otherwise>
    <xsl:value-of select="$genitive_plural"/>
   </xsl:otherwise>
  </xsl:choose>
</xsl:template>
</xsl:stylesheet>

[/code]
iq-site
22 декабря 2010 г.
#
Re: XSL шаблон вывода галереи
iqsite, position() учитывает все узлы, которые переданы конкретному темплейту для обработки. Чтобы элементы без галочки в допсвойстве не учитывались в position() нужно перенести условие выше, из теплейта обрабатывающего элементы ИС - в вызов этого темплейта.
Для этого строку
<xsl:call-template name="items">
надо заменить на:
<xsl:apply-template match="//blocks/items/item[item_propertys/property[@xml_name='xml-имядопсвойства']/value = 1]">
Заказов не беру. Консультирую редко.
22 декабря 2010 г.
#
Re: XSL шаблон вывода галереи
Спасибо, натолкнули на правильный путь, но вот если просто заменить как вы сказали выдаёт кучу ошибок.
Пробую так:

    <xsl:apply-templates select="//blocks/items/item[item_propertys/property[@xml_name='show_element']/value = 1]">
     <xsl:with-param name="items_in_line" select="$items_in_line"/>
     <xsl:with-param name="current_position" select="0"/>
    </xsl:apply-templates>


<xsl:template match="//blocks/items/item[item_propertys/property[@xml_name='show_element']/value = 1]">
  <xsl:param name="items_in_line"/>
  <xsl:param name="current_position"/>
   <tr align="center" valign="top">
    <xsl:for-each select="//blocks/items/item[item_status=1]">
   

   
     <xsl:if test="position() > $current_position and ($current_position + $items_in_line) >= position()">
      <td>
       <xsl:if test="item_small_image!=''">
        <!-- Проверяем задан ли путь к файлу большого изображения -->
        <xsl:if test="item_image!=''">
         <a href="{item_image}" target="_blank" title="Увеличить">
          <img src="{item_small_image}" title="{item_name}" alt="{item_name}" />
          <p><xsl:value-of disable-output-escaping="yes" select="item_name"/></p>
         </a>
        </xsl:if>
        <xsl:if test="item_image = ''">
         <img src="{item_small_image}" title="{item_name}" alt="{item_name}" />
         <p><xsl:value-of disable-output-escaping="yes" select="item_name"/></p>
        </xsl:if>
       </xsl:if>
      </td>
     </xsl:if>
   
    </xsl:for-each>
   </tr>
  <xsl:if test="count(//blocks/items/item[item_status=1]) > ($current_position + $items_in_line)">
   <xsl:apply-templates select="//blocks/items/item[item_propertys/property[@xml_name='show_element']/value = 1]">
    <xsl:with-param name="items_in_line" select="$items_in_line"/>
    <xsl:with-param name="current_position" select="$current_position + $items_in_line"/>
   </xsl:apply-templates>
  </xsl:if>
</xsl:template>

- Так просто ничего не выводит... Чувствую что косяк в select и match..
Знаний не хватает, помогите разобраться пожалуйста!
iq-site
22 декабря 2010 г.
#
Re: XSL шаблон вывода галереи
Блин, я выше ерунду написал, извините.
В вызове темплейта должен быть select а не match
<xsl:apply-template select="//blocks/items/item[item_propertys/property[@xml_name='xml-имядопсвойства']/value = 1]">


Ну и у вас тоже неправильно.
В самом темплейте как раз match, но в нем не должно быть никаких условий, и полный путь тоже не обязателен. И зачем внутри темплейта for-each? И зачем вы его вызываетет рекурисвно?? О_о Йафшоке...

Вот вам правильный, рациональный код:
<?xml version="1.0" encoding="windows-1251"?>
<!DOCTYPE xsl:stylesheet>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output xmlns="http://www.w3.org/TR/xhtml1/strict" doctype-public="-//W3C//DTD XHTML 1.0 Strict//EN" encoding="Windows-1251" indent="yes" method="html" omit-xml-declaration="no" version="1.0" media-type="text/xml"/>

   <!-- СписокКартинок -->

   <xsl:template match="/">
      <xsl:apply-templates select="/document"/>
   </xsl:template>

   <xsl:template match="/document">

      <!-- Получаем ID родительской группы и записываем в переменную $parent_group_id -->
      <xsl:variable name="parent_group_id" select="blocks/parent_group_id"/>

      <!-- Если в находимся корне - выводим название информационной системы -->
      <xsl:if test="blocks/parent_group_id = 0">
         <h1>
            <xsl:value-of disable-output-escaping="yes" select="blocks/name"/>
         </h1>

         <!-- Описание выводится при отсутствии фильтрации по тэгам -->
         <xsl:if test="count(blocks/tags/tag) = 0">
            <xsl:value-of disable-output-escaping="yes" select="blocks/description"/>
         </xsl:if>
      </xsl:if>

      <!-- Если в находимся в группе - выводим название группы -->
      <xsl:if test="blocks/parent_group_id != 0">
         <h1>
            <xsl:value-of disable-output-escaping="yes" select=".//group[@id=$parent_group_id]/name"/>
         </h1>

         <!-- Описание выводим только на первой странице -->
         <xsl:if test="blocks/items/current_page = 0">
            <xsl:value-of disable-output-escaping="yes" select=".//group[@id=$parent_group_id]/description"/>
         </xsl:if>
      </xsl:if>

      <!-- Обработка выбранных тэгов -->
      <xsl:if test="count(blocks/selected_tags/tag) = 1">
         <h2>Метка &#x97; <strong><xsl:value-of select="blocks/selected_tags/tag/tag_name"/></strong>.</h2>
      </xsl:if>

      <!-- Отображение подгрупп данной группы, только если подгруппы есть и не идет фильтра по меткам -->
      <xsl:if test="count(blocks/selected_tags/tag) = 0 and count(.//group[@parent_id=$parent_group_id]) &gt; 0">
         <xsl:apply-templates select=".//group[@parent_id=$parent_group_id]" mode="groups"/>
      </xsl:if>

      <xsl:if test="count(blocks/items/item[item_status=1]) &gt; 0">
         <!-- Число элементов в строку -->
         <xsl:variable name="items_in_line" select="3"/>
         <!-- jQuery lightbox -->
         <div id="gallery" align="center">
            <table border="0" cellspacing="20" cellpadding="0">
               <tr align="center" valign="top">
                  <xsl:apply-templates select="blocks/items/item[item_propertys/property[@xml_name='show_element']/value = 1]">
                     <xsl:with-param name="items_in_line" select="$items_in_line"/>
                  </xsl:apply-templates>
               </tr>
            </table>
         </div>
      </xsl:if>

      <!-- Строка ссылок на другие страницы информационной системы -->
      <xsl:if test="ОтображатьСсылкиНаСледующиеСтраницы=1">
         <p class="pages_nav">
            <!-- Ссылка, для которой дописываются суффиксы page-XX/ -->
            <xsl:variable name="link">
               <xsl:value-of select="/document/blocks/url"/>
               <xsl:if test="$parent_group_id != 0">
                  <xsl:value-of select="/document/blocks//group[@id = $parent_group_id]/fullpath"/>
               </xsl:if>
            </xsl:variable>

            <xsl:call-template name="for">
               <xsl:with-param name="link" select="$link"/>
               <xsl:with-param name="items_on_page" select="blocks/items/items_on_page"/>
               <xsl:with-param name="current_page" select="blocks/items/current_page"/>
               <xsl:with-param name="count_items" select="blocks/items/count_items"/>
               <xsl:with-param name="visible_pages">999</xsl:with-param>
            </xsl:call-template>
         </p>
      </xsl:if>

      <div style="clear: both"></div>

      <!-- Rss -->
      <!--<div class="rss_4_ie"></div>
  <a href="{blocks/url}rss/">
   <img src="/images/rss/rss_2.0.png" style="filter: alpha(opacity=0); margin: 0px 0px -4px 0px"/>
  </a>
  <a href="{blocks/url}rss/">RSS</a>-->

      <xsl:if test="ОтображатьСсылкуНаАрхив = 1">
         <div class="archives_4_ie"></div>
         <a href="{blocks/url}">
            <img src="/images/archives.png" style="filter: alpha(opacity=0); margin: 0px 0px -4px 0px"/>
         </a>
         <a href="{blocks/url}">Архив "<xsl:value-of disable-output-escaping="yes" select="blocks/name"/>"</a>
      </xsl:if>
   </xsl:template>

   <!-- Шаблон выводит рекурсивно ссылки на группы инф. элемента -->
   <xsl:template match="group" mode="goup_path">
      <xsl:variable name="parent_id" select="@parent_id"/>

      <xsl:apply-templates select="//group[@id=$parent_id]" mode="goup_path"/>

      <xsl:if test="@parent_id=0">
         <a href="{/document/blocks/url}">
            <xsl:value-of disable-output-escaping="yes" select="/document/blocks/name"/>
         </a>
      </xsl:if>

      <span class="path_arrow">&#x2192;</span>

      <a href="{/document/blocks/url}{fullpath}">
         <xsl:value-of disable-output-escaping="yes" select="name"/>
      </a>
   </xsl:template>

   <!-- Шаблон выводит ссылки подгруппы информационного элемента -->
   <xsl:template match="group" mode="groups">
      <div class="group_gallery">

         <a href="{/document/blocks/url}{fullpath}">
            <b>
               <xsl:value-of disable-output-escaping="yes" select="name"/>
            </b>
         </a>&#xA0;<span style="color: #b7af9c">(<xsl:value-of select="count_all_items"/>)</span><xsl:value-of disable-output-escaping="yes" select="description"/></div>
   </xsl:template>

   <xsl:template match="item">
      <xsl:param name="items_in_line"/>

      <td>
         <xsl:if test="item_small_image!=''">
            <!-- Проверяем задан ли путь к файлу большого изображения -->            
            <xsl:if test="item_image!=''">
               <a href="{item_image}" target="_blank" title="Увеличить">
                  <img src="{item_small_image}" title="{item_name}" alt="{item_name}"/>
                  <p>
                     <xsl:value-of disable-output-escaping="yes" select="item_name"/>
                  </p>
               </a>
            </xsl:if>
            <xsl:if test="item_image = ''">
               <img src="{item_small_image}" title="{item_name}" alt="{item_name}"/>
               <p>
                  <xsl:value-of disable-output-escaping="yes" select="item_name"/>
               </p>
            </xsl:if>
         </xsl:if>
      </td>

      <xsl:if test="position() mod $items_in_line = 0">
         <xsl:text disable-output-escaping="yes">&lt;/tr>&lt;tr align="center" valign="top"></xsl:text>
      </xsl:if>
   </xsl:template>

   <!-- /// Метки для информационного элемента /// -->
   <xsl:template match="tags/tag">
      <a href="{/document/blocks/url}tag/{tag_path_name}/" class="tag">
         <xsl:value-of select="tag_name"/>
      </a>
      <xsl:if test="position() != last()">,</xsl:if>&#xA0;</xsl:template>

   <!-- Цикл для вывода строк ссылок -->
   <xsl:template name="for">
      <xsl:param name="i" select="0"/>
      <xsl:param name="prefix">page</xsl:param>
      <xsl:param name="link"/>
      <xsl:param name="items_on_page"/>
      <xsl:param name="current_page"/>
      <xsl:param name="count_items"/>
      <xsl:param name="visible_pages"/>

      <xsl:variable name="n" select="$count_items div $items_on_page"/>

      <!-- Заносим в переменную $parent_group_id идентификатор текущей группы -->
      <xsl:variable name="parent_group_id" select="/document/blocks/parent_group_id"/>


      <!-- Считаем количество выводимых ссылок перед текущим элементом -->
      <xsl:variable name="pre_count_page">
         <xsl:choose>
            <xsl:when test="$current_page &gt; ($n - (round($visible_pages div 2) - 1))">
               <xsl:value-of select="$visible_pages - ($n - $current_page)"/>
            </xsl:when>
            <xsl:otherwise>
               <xsl:value-of select="round($visible_pages div 2) - 1"/>
            </xsl:otherwise>
         </xsl:choose>
      </xsl:variable>

      <!-- Считаем количество выводимых ссылок после текущего элемента -->
      <xsl:variable name="post_count_page">
         <xsl:choose>
            <xsl:when test="0 &gt; $current_page - (round($visible_pages div 2) - 1)">
               <xsl:value-of select="$visible_pages - $current_page - 1"/>
            </xsl:when>
            <xsl:otherwise>
               <xsl:choose>
                  <xsl:when test="round($visible_pages div 2) = ($visible_pages div 2)">
                     <xsl:value-of select="$visible_pages div 2"/>
                  </xsl:when>
                  <xsl:otherwise>
                     <xsl:value-of select="round($visible_pages div 2) - 1"/>
                  </xsl:otherwise>
               </xsl:choose>
            </xsl:otherwise>
         </xsl:choose>
      </xsl:variable>

      <xsl:if test="($count_items &gt; $items_on_page) and $i = 0">Страница</xsl:if>

      <xsl:if test="$count_items &gt; $items_on_page and $n &gt; $i">
         <!-- Определяем адрес тэга -->
         <xsl:variable name="tag_link">
            <xsl:choose>
               <!-- Если не нулевой уровень -->
               <xsl:when test="count(/document/blocks/selected_tags/tag) != 0">tag/<xsl:value-of select="/document/blocks/selected_tags/tag/tag_path_name"/>/</xsl:when>
               <!-- Иначе если нулевой уровень - просто ссылка на страницу со списком элементов -->
               <xsl:otherwise></xsl:otherwise>
            </xsl:choose>
         </xsl:variable>

         <!-- Определяем адрес ссылки -->
         <xsl:variable name="number_link">
            <xsl:choose>
               <!-- Если не нулевой уровень -->
               <xsl:when test="$i != 0">
                  <xsl:value-of select="$prefix"/>-<xsl:value-of select="$i + 1"/>/</xsl:when>
               <!-- Иначе если нулевой уровень - просто ссылка на страницу со списком элементов -->
               <xsl:otherwise></xsl:otherwise>
            </xsl:choose>
         </xsl:variable>

         <!-- Ставим ссылку на страницу-->
         <xsl:if test="$i != $current_page">
            <!-- Выводим ссылку на первую страницу -->
            <xsl:if test="$current_page - $pre_count_page &gt; 0 and $i = 0">
               <a href="{$link}" class="page_link" style="text-decoration: none;">&#x2190;</a>
            </xsl:if>

            <xsl:choose>
               <xsl:when test="$i &gt;= ($current_page - $pre_count_page) and ($current_page + $post_count_page) &gt;= $i">
                  <!-- Выводим ссылки на видимые страницы -->
                  <a href="{$link}{$tag_link}{$number_link}" class="page_link">
                     <xsl:value-of select="$i + 1"/>
                  </a>
               </xsl:when>
               <xsl:otherwise></xsl:otherwise>
            </xsl:choose>

            <!-- Выводим ссылку на последнюю страницу -->
            <xsl:if test="$i+1 &gt;= $n and $n &gt; ($current_page + 1 + $post_count_page)">
               <xsl:choose>
                  <xsl:when test="$n &gt; round($n)">
                     <!-- Выводим ссылку на последнюю страницу -->
                     <a href="{$link}{$prefix}-{round($n+1)}/" class="page_link" style="text-decoration: none;">&#x2192;</a>
                  </xsl:when>
                  <xsl:otherwise>
                     <a href="{$link}{$prefix}-{round($n)}/" class="page_link" style="text-decoration: none;">&#x2192;</a>
                  </xsl:otherwise>
               </xsl:choose>
            </xsl:if>
         </xsl:if>

         <!-- Ссылка на следующую страницу для Ctrl + вправо -->
         <xsl:if test="($n - 1) &gt; $current_page and $i = $current_page">
            <a href="{$link}{$tag_link}page-{$current_page+2}/" id="id_next"></a>
         </xsl:if>

         <!-- Не ставим ссылку на страницу-->
         <xsl:if test="$i = $current_page">
            <span class="current">
               <xsl:value-of select="$i+1"/>
            </span>
         </xsl:if>

         <!-- Рекурсивный вызов шаблона. НЕОБХОДИМО ПЕРЕДАВАТЬ ВСЕ НЕОБХОДИМЫЕ ПАРАМЕТРЫ! -->
         <xsl:call-template name="for">
            <xsl:with-param name="i" select="$i + 1"/>
            <xsl:with-param name="prefix" select="$prefix"/>
            <xsl:with-param name="link" select="$link"/>
            <xsl:with-param name="items_on_page" select="$items_on_page"/>
            <xsl:with-param name="current_page" select="$current_page"/>
            <xsl:with-param name="count_items" select="$count_items"/>
            <xsl:with-param name="visible_pages" select="$visible_pages"/>
         </xsl:call-template>
      </xsl:if>
   </xsl:template>

   <!-- Склонение после числительных -->
   <xsl:template name="declension">

      <xsl:param name="number" select="number"/>

      <!-- Именительный падеж -->
      <xsl:variable name="nominative">
         <xsl:text>комментарий</xsl:text>
      </xsl:variable>

      <!-- Родительный падеж, единственное число -->
      <xsl:variable name="genitive_singular">
         <xsl:text>комментария</xsl:text>
      </xsl:variable>


      <xsl:variable name="genitive_plural">
         <xsl:text>комментариев</xsl:text>
      </xsl:variable>

      <xsl:variable name="last_digit">
         <xsl:value-of select="$number mod 10"/>
      </xsl:variable>

      <xsl:variable name="last_two_digits">
         <xsl:value-of select="$number mod 100"/>
      </xsl:variable>

      <xsl:choose>
         <xsl:when test="$last_digit = 1 and $last_two_digits != 11">
            <xsl:value-of select="$nominative"/>
         </xsl:when>
         <xsl:when test="$last_digit = 2 and $last_two_digits != 12    or $last_digit = 3 and $last_two_digits != 13    or $last_digit = 4 and $last_two_digits != 14">
            <xsl:value-of select="$genitive_singular"/>
         </xsl:when>
         <xsl:otherwise>
            <xsl:value-of select="$genitive_plural"/>
         </xsl:otherwise>
      </xsl:choose>
   </xsl:template>
</xsl:stylesheet>
Заказов не беру. Консультирую редко.
22 декабря 2010 г.
#
Re: XSL шаблон вывода галереи
Спасибо большое, ошибок не выдаёт, уже чтото). Но вот только я уже всю голову сломал -
В xml нужное свойство передаётся:

<item_propertys>
   <item_property type="Checkbox" xml_name="show_element" parent_id="0" id="17">
      <property_id>103</property_id>
      <property_xml_name>show_element</property_xml_name>
      <property_name>Отображать в галерее</property_name>
      <property_order>0</property_order>
      <show_element>1</show_element>
      <value>1</value>
   </item_property>
</item_propertys>


А при проверке значения ничего не выводится(

<xsl:apply-templates select="blocks/items/item[item_propertys/property[@xml_name='show_element']/value = 1]">
<xsl:with-param name="items_in_line" select="$items_in_line"/>
</xsl:apply-templates>
iq-site
22 декабря 2010 г.
#
Re: XSL шаблон вывода галереи
[item_propertys/item_property
а не
[item_propertys/property
23 декабря 2010 г.
#
Re: XSL шаблон вывода галереи
h4mpy, спасибо, поправили меня ) Что-то я сегодня рассеян как никогда
Заказов не беру. Консультирую редко.
23 декабря 2010 г.
#
Re: XSL шаблон вывода галереи
Большое Человеческое Спасибо! Теперь работает!!
iq-site
27 декабря 2010 г.
#
Re: XSL шаблон вывода галереи
Ещё небольшой вопрос по тому же шаблону.

У меня все элементы помещаются на одной странице, а все равно выводится навигация на две страницы((

Т.е. невидимые элементы присутствуют в переменной blocks/items/count_items. Как это лечить, подскажите пожалуйста!
iq-site
27 декабря 2010 г.
#
Re: XSL шаблон вывода галереи
заменить
<xsl:with-param name="count_items" select="blocks/items/count_items"/>
на
<xsl:with-param name="count_items" select="count(blocks/items/item[item_propertys/property[@xml_name='show_element']/value = 1])"/>
Заказов не беру. Консультирую редко.
Авторизация
Регистрация
+7 (495) 223-46-50
+7 (812) 448-38-90
8 (800) 333-49-91
Работаем c 9:00 до 18:00
Политика обработки персональных данных
Продолжая использовать сайт, вы даете согласие на обработку файлов «cookie» (представляют собой небольшие файлы, содержащие информацию о предыдущих посещениях сайта) и пользовательских данных на условиях политики обработки.
Редакции HostCMS Области применения
Возможности Поддержка
О HostCMS Заказать сайт Партнерская программа
© 2005—2026 ООО «Хостмэйк»

Мы используем куки (небольшие файлы, содержащие информацию о предыдущих посещениях сайта) и обработку пользовательских данных с помощью Яндекс.Метрики для лучшей работы сайта.
Оставаясь с нами, вы соглашаетесь на использование файлов куки.