HostCMS → Форум → Общие вопросы по системе управления сайтом HostCMS v. 5 → добавление товара в корзину

добавление товара в корзину
19 апреля 2011 г.
#
добавление товара в корзину
Здравствуйте.

Я делал добавление товара в корзину, без перезагрузки страницы, по примеру от: natalya который находится на этой странице , все сделал, только ссылка добавления товара не получает id товара. Вот страничка номер 1 тут кнопка добавления товара не работает, а вот страница номер 2 все нормально работает.


Вот сам код XSL шаблона, странички номер 1, соответственно где не работающая кнопка


<?xml version="1.0" encoding="utf-8"?>
<!DOCTYPE xsl:stylesheet>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output xmlns="http://www.w3.org/TR/xhtml1/strict" doctype-public="-//W3C//DTD XHTML 1.0 Strict//EN" encoding="utf-8" indent="yes" method="html" omit-xml-declaration="no" version="1.0" media-type="text/xml"/>
   
   
   <xsl:template match="/">
      <xsl:apply-templates select="/document"/>
   </xsl:template>
   <xsl:template match="/document">
      
      
      
      <h3>Поиск, результаты поиска по артиклу</h3>
      <!-- Форма поиска -->
      <div id="search" style="overflow:hidden; float:none !important; margin: 0 auto; width:350px;">
         <form method="get" action="/search/" id="form_search"><input type="text" name="text" value="{search_query}" maxlength="200" id="search_val" style="width:260px !important" class="search" title="укажите артикул для поиска"/><input type="image" id="button" src="/images/top_but.png" /></form>
      </div>
      <xsl:if test="search_query!=''">
         <p>
            <br />
            <strong>Найдено товаров:</strong>&#xA0;<xsl:value-of select="count_items"/>&#xA0;<xsl:call-template name="declension">
            <xsl:with-param name="number" select="count_items"/></xsl:call-template>.</p>
         <xsl:if test="count_items!=0">
            <table cellspacing="0" cellpadding="0" border="0" class="searhList">
               <tr>
                  <th>Фирма</th>
                  <th>Артикул</th>
                  <th >Наименование</th>
                  <th>Цена, руб</th>
                  <th>Цена, доставки</th>
                  <th >Вес нетто, кг</th>
                  <th>Срок доставки</th>
                  
                  <th width="30"></th>
               </tr>
               <xsl:apply-templates select="item">
               </xsl:apply-templates>
            </table>
            <!-- Строка ссылок на другие страницы результата поиска -->
            <xsl:variable name="count_pages" select="ceiling(count_items div items_on_page)"/>
            <xsl:variable name="visible_pages" select="5"/>
            <xsl:variable name="real_visible_pages"><xsl:choose>
                  <xsl:when test="$count_pages &lt; $visible_pages"><xsl:value-of select="$count_pages"/></xsl:when>
                  <xsl:otherwise><xsl:value-of select="$visible_pages"/></xsl:otherwise>
            </xsl:choose></xsl:variable>
            <!-- Считаем количество выводимых ссылок перед текущим элементом -->
            <xsl:variable name="pre_count_page"><xsl:choose>
                  <xsl:when test="(current_page - 1) - (floor($real_visible_pages div 2)) &lt; 0">
                     <xsl:value-of select="current_page - 1"/>
                  </xsl:when>
                  <xsl:when test="($count_pages - (current_page - 1) - 1) &lt; floor($real_visible_pages div 2)">
                     <xsl:value-of select="$real_visible_pages - ($count_pages - (current_page - 1) - 1) - 1"/>
                  </xsl:when>
                  <xsl:otherwise>
                     <xsl:choose>
                        <xsl:when test="round($real_visible_pages div 2) = $real_visible_pages div 2">
                           <xsl:value-of select="floor($real_visible_pages div 2) - 1"/>
                        </xsl:when>
                        <xsl:otherwise>
                           <xsl:value-of select="floor($real_visible_pages div 2)"/>
                        </xsl:otherwise>
                     </xsl:choose>
                  </xsl:otherwise>
            </xsl:choose></xsl:variable>
            <!-- Считаем количество выводимых ссылок после текущего элемента -->
            <xsl:variable name="post_count_page"><xsl:choose>
                  <xsl:when test="0 &gt; (current_page - 1) - (floor($real_visible_pages div 2) - 1)">
                     <xsl:value-of select="$real_visible_pages - (current_page - 1) - 1"/>
                  </xsl:when>
                  <xsl:when test="($count_pages - (current_page - 1) - 1) &lt; floor($real_visible_pages div 2)">
                     <xsl:value-of select="$real_visible_pages - $pre_count_page - 1"/>
                  </xsl:when>
                  <xsl:otherwise>
                     <xsl:value-of select="$real_visible_pages - $pre_count_page - 1"/>
                  </xsl:otherwise>
            </xsl:choose></xsl:variable>
            <xsl:variable name="i"><xsl:choose>
                  <xsl:when test="(current_page - 1) + 1 = $count_pages"><xsl:value-of select="(current_page - 1) - $real_visible_pages + 1"/></xsl:when>
                  <xsl:when test="(current_page - 1) - $pre_count_page &gt; 0"><xsl:value-of select="(current_page - 1) - $pre_count_page"/></xsl:when>
                  <xsl:otherwise>0</xsl:otherwise>
            </xsl:choose></xsl:variable>
            <xsl:call-template name="for">
               <xsl:with-param name="items_on_page" select="items_on_page"/>
               <xsl:with-param name="current_page" select="current_page - 1"/>
               <xsl:with-param name="count_items" select="count_items"/>
               <xsl:with-param name="i" select="$i"/>
               <xsl:with-param name="post_count_page" select="$post_count_page"/>
               <xsl:with-param name="pre_count_page" select="$pre_count_page"/>
               <xsl:with-param name="visible_pages" select="$real_visible_pages"/>
            </xsl:call-template>
            <div style="clear: both"></div>
         </xsl:if>
      </xsl:if>
      <xsl:if test="search_query = ''">
         <p>Введите поисковой запрос.</p>
      </xsl:if>
   </xsl:template>
   <xsl:template match="item">
      <tr class="shop_cart_table">
         <td>
            <xsl:value-of select="item/producer/shop_producers_list_name"/>
         </td>
         <td>
            <xsl:value-of select="item/marking_of_goods"/>
         </td>
         <td>
            <xsl:value-of select="page_name"/>
         </td>
         <td>
            <xsl:value-of select="item/price"/>
         </td>
         <td>
            <xsl:if test="item/property[@xml_name='price_delivery'] != ''">
               <xsl:value-of select="item/property[@xml_name='price_delivery']/value"/>
            </xsl:if>
         </td>
         <td>
            <xsl:value-of select="item/weight"/>
         </td>
         
         
         
         
         
         
         
         <!-- <td>
            наличие
            <xsl:if test="item/rest &gt; 0">
               <img alt="В корзину" title="В корзину" src="/images/nali.png" />
            </xsl:if>
            <xsl:if test="item/rest = 0">
               заказ
            </xsl:if>
            <xsl:if test="item/rest = -1">
               нет
            </xsl:if>
         </td> -->
         <td>
            <xsl:if test="item/property[@xml_name='date_delivery'] != ''">
               <xsl:value-of select="item/property[@xml_name='date_delivery']/value"/>
            </xsl:if>
         </td>
         <td>
            
            <!-- Ссылка на добавление товара в корзину -->
            
            <a href="{/shop/path}cart/?action=add&amp;item_id={@id}" onclick="return AddIntoCart('{/shop/path}', {@id}, document.getElementById('count_{@id}').value)"><img alt="В корзину" title="В корзину" src="/images/basketBtn.png" style="margin: 0px 0px -4px 10px" /></a>
            
            
            
            
            
            
            
            
            
         </td>
      </tr>
   </xsl:template>
   <xsl:template name="page_address" match="text()">
      <xsl:param name="str" select="."/>
      <xsl:param name="max">50</xsl:param>
      <xsl:param name="hvost">10</xsl:param>
      <xsl:param name="begin">
         <xsl:choose>
            <xsl:when test="string-length($str) &gt; $max">
               <xsl:value-of select="substring($str, 1, $max - $hvost)"/>
            </xsl:when>
            <xsl:otherwise>
               <xsl:value-of select="substring($str, 1)"/>
            </xsl:otherwise>
         </xsl:choose>
      </xsl:param>
      <xsl:param name="end">
         <xsl:choose>
            <xsl:when test="string-length($str) &gt; $max">
               <xsl:value-of select="substring($str, string-length($str) - $hvost + 1, $hvost)"/>
            </xsl:when>
            <xsl:otherwise>
            </xsl:otherwise>
         </xsl:choose>
      </xsl:param>
      <xsl:param name="result">
         <xsl:choose>
            <xsl:when test="$end != ''">
               <xsl:value-of select="concat($begin, '…', $end)"/>
            </xsl:when>
            <xsl:otherwise>
               <xsl:value-of select="$begin"/>
            </xsl:otherwise>
         </xsl:choose>
      </xsl:param>
      <xsl:value-of disable-output-escaping="yes" select="$result"/>
   </xsl:template>
   <!-- Цикл для вывода строк ссылок -->
   <xsl:template name="for">
      <xsl:param name="items_on_page"/>
      <xsl:param name="current_page"/>
      <xsl:param name="pre_count_page"/>
      <xsl:param name="post_count_page"/>
      <xsl:param name="i" select="0"/>
      <xsl:param name="count_items"/>
      <xsl:param name="visible_pages"/>
      <xsl:param name="prefix">page</xsl:param>
      <xsl:variable name="n" select="ceiling($count_items div $items_on_page)"/>
      <xsl:variable name="start_page"><xsl:choose>
            <xsl:when test="$current_page + 1 = $n"><xsl:value-of select="$current_page - $visible_pages + 1"/></xsl:when>
            <xsl:when test="$current_page - $pre_count_page &gt; 0"><xsl:value-of select="$current_page - $pre_count_page"/></xsl:when>
            <xsl:otherwise>0</xsl:otherwise>
      </xsl:choose></xsl:variable>
      <xsl:if test="$i = $start_page and $current_page != 0">
         <span class="ctrl">
            &#8592; Ctrl
         </span>
      </xsl:if>
      <xsl:if test="$i = ($current_page + $post_count_page + 1) and $n != ($current_page+1)">
         <span class="ctrl">
            Ctrl &#8594;
         </span>
      </xsl:if>
      <xsl:if test="$count_items &gt; $items_on_page and ($current_page + $post_count_page + 1) &gt; $i">
         <!-- Определяем адрес ссылки -->
         <xsl:variable name="number_link">
            <xsl:choose>
               <!-- Если не нулевой уровень -->
               <xsl:when test="$i != 0">&amp;<xsl:value-of select="$prefix"/>=<xsl:value-of select="$i + 1"/></xsl:when>
               <!-- Иначе если нулевой уровень - просто ссылка на страницу со списком элементов -->
               <xsl:otherwise></xsl:otherwise>
            </xsl:choose>
         </xsl:variable>
         <!-- Выводим ссылку на первую страницу -->
         <xsl:if test="$current_page - $pre_count_page &gt; 0 and $i = $start_page">
            <a href="./?text={search_query_url}" class="page_link" style="text-decoration: none;">&#x2190;</a>
         </xsl:if>
         <!-- Ставим ссылку на страницу-->
         <xsl:if test="$i != $current_page">
            <xsl:if test="($current_page - $pre_count_page) &lt;= $i and $i &lt; $n">
               <!-- Выводим ссылки на видимые страницы -->
               <a href="./?text={search_query_url}{$number_link}" class="page_link">
                  <xsl:value-of select="$i + 1"/>
               </a>
            </xsl:if>
            <!-- Выводим ссылку на последнюю страницу -->
            <xsl:if test="$i+1 &gt;= ($current_page + $post_count_page + 1) and $n &gt; ($current_page + 1 + $post_count_page)">
               <a href="./?text={search_query_url}&amp;{$prefix}={$n}" class="page_link" style="text-decoration: none;">&#x2192;</a>
            </xsl:if>
         </xsl:if>
         <!-- Ссылка на предыдущую страницу для Ctrl + влево -->
         <xsl:if test="$current_page != 0 and $i = $current_page">
            <xsl:variable name="prev_number_link">
               <xsl:choose>
                  <!-- Если не нулевой уровень -->
                  <xsl:when test="($current_page - 1) != 0">page-<xsl:value-of select="$i"/>/</xsl:when>
                  <!-- Иначе если нулевой уровень - просто ссылка на страницу со списком элементов -->
                  <xsl:otherwise></xsl:otherwise>
               </xsl:choose>
            </xsl:variable>
            <a href="./?text={search_query_url}{$prev_number_link}" id="id_prev"></a>
         </xsl:if>
         <!-- Ссылка на следующую страницу для Ctrl + вправо -->
         <xsl:if test="($n - 1) > $current_page and $i = $current_page">
            <a href="./?text={search_query_url}&amp;{$prefix}={$current_page+2}" id="id_next"></a>
         </xsl:if>
         <!-- Не ставим ссылку на страницу-->
         <xsl:if test="$i = $current_page">
            <span class="current">
               <xsl:value-of select="$i+1"/>
            </span>
         </xsl:if>
         <!-- Рекурсивный вызов шаблона. НЕОБХОДИМО ПЕРЕДАВАТЬ ВСЕ НЕОБХОДИМЫЕ ПАРАМЕТРЫ! -->
         <xsl:call-template name="for">
            <xsl:with-param name="i" select="$i + 1"/>
            <xsl:with-param name="items_on_page" select="$items_on_page"/>
            <xsl:with-param name="current_page" select="$current_page"/>
            <xsl:with-param name="count_items" select="$count_items"/>
            <xsl:with-param name="pre_count_page" select="$pre_count_page"/>
            <xsl:with-param name="post_count_page" select="$post_count_page"/>
            <xsl:with-param name="visible_pages" select="$visible_pages"/>
         </xsl:call-template>
      </xsl:if>
   </xsl:template>
   <!-- Склонение после числительных -->
   <xsl:template name="declension">
      <xsl:param name="number" select="number"/>
      <!-- Именительный падеж -->
      <xsl:variable name="nominative">
         <xsl:text>товар</xsl:text>
      </xsl:variable>
      <!-- Родительный падеж, единственное число -->
      <xsl:variable name="genitive_singular">
         <xsl:text>товара</xsl:text>
      </xsl:variable>
      <xsl:variable name="genitive_plural">
         <xsl:text>товаров</xsl:text>
      </xsl:variable>
      <xsl:variable name="last_digit">
         <xsl:value-of select="$number mod 10"/>
      </xsl:variable>
      <xsl:variable name="last_two_digits">
         <xsl:value-of select="$number mod 100"/>
      </xsl:variable>
      <xsl:choose>
         <xsl:when test="$last_digit = 1 and $last_two_digits != 11">
            <xsl:value-of select="$nominative"/>
         </xsl:when>
         <xsl:when test="$last_digit = 2 and $last_two_digits != 12 or $last_digit = 3 and $last_two_digits != 13 or $last_digit = 4 and $last_two_digits != 14">
            <xsl:value-of select="$genitive_singular"/>
         </xsl:when>
         <xsl:otherwise>
            <xsl:value-of select="$genitive_plural"/>
         </xsl:otherwise>
      </xsl:choose>
   </xsl:template>
</xsl:stylesheet>
19 апреля 2011 г.
#
Re: добавление товара в корзину
в xml поиска нет узла /shop/path, возможно есть другой узел
а вместо @id - item/@id

получается:
Было:
<a href="{/shop/path}cart/?action=add&amp;item_id={@id}" onclick="return AddIntoCart('{/shop/path}', {@id}, document.getElementById('count_{@id}').value)"><img alt="В корзину" title="В корзину" src="/images/basketBtn.png" style="margin: 0px 0px -4px 10px" /></a>


Должно быть:
<a href="/internet-magazin/cart/?action=add&amp;item_id={item/@id}" onclick="return AddIntoCart('/internet-magazin/', {item/@id}, document.getElementById('count_{item/@id}').value)"><img alt="В корзину" title="В корзину" src="/images/basketBtn.png" style="margin: 0px 0px -4px 10px" /></a>

+можно посмотреть в xml где хранится путь к магазину и заменить /internet-magazin/ на {путь к переменной}
19 апреля 2011 г.
#
Re: добавление товара в корзину
h4mpy,
Спасибо огромное! h4mpy писал(а):
а вместо @id — item/@id
  помогло
19 апреля 2011 г.
#
Re: добавление товара в корзину
Ну с id товара разобрались, но к сожалению при нажатии кнопки покупки товара, все ровно выполняется переход в корзину, как от этого избавиться?
20 апреля 2011 г.
#
Re: добавление товара в корзину
Я так пониманию, не получается реализовать добавление товара без перезагрузки, потомучто h4mpy писал(а):
в xml поиска нет узла /shop/path, возможно есть другой узел
 ?
20 апреля 2011 г.
#
Re: добавление товара в корзину
нет поля с количеством

можете поставить 1
<a href="/internet-magazin/cart/?action=add&amp;item_id={item/@id}" onclick="return AddIntoCart('/internet-magazin/', {item/@id}, 1)"><img alt="В корзину" title="В корзину" src="/images/basketBtn.png" style="margin: 0px 0px -4px 10px" /></a>


или добавить поле ввода
<input size="3" value="1" id="count_{item/@id}" type="text"/>
20 апреля 2011 г.
#
Re: добавление товара в корзину
Теперь все работает как и хотел, Спасибо. h4mpy
Авторизация
Регистрация
+7 (495) 223-46-50
+7 (812) 448-38-90
8 (800) 333-49-91
Работаем c 9:00 до 18:00
Политика обработки персональных данных
Продолжая использовать сайт, вы даете согласие на обработку файлов «cookie» (представляют собой небольшие файлы, содержащие информацию о предыдущих посещениях сайта) и пользовательских данных на условиях политики обработки.
Редакции HostCMS Области применения
Возможности Поддержка
О HostCMS Заказать сайт Партнерская программа
© 2005—2026 ООО «Хостмэйк»

Мы используем куки (небольшие файлы, содержащие информацию о предыдущих посещениях сайта) и обработку пользовательских данных с помощью Яндекс.Метрики для лучшей работы сайта.
Оставаясь с нами, вы соглашаетесь на использование файлов куки.