Отображение свойства товара в сравнении

<xsl:template match="property_value"> ... </xsl:template>

   <!-- Шаблон вывода значений свойств -->
   <xsl:template match="property_value">
      <xsl:variable name="property_id" select="property_id" />
      <xsl:variable name="type" select="/shop/shop_item_properties//property[@id=$property_id]/type" />
      
      <xsl:choose>
         <!-- File -->
         <xsl:when test="$type = 2">
            <a target="_blank" href="{../dir}{file}"><xsl:value-of select="file_name"/></a>
         </xsl:when>
         <!-- Wysiwyg -->
         <xsl:when test="$type = 6">
            <xsl:value-of disable-output-escaping="yes" select="value"/>
         </xsl:when>
         <!-- Checkbox -->
         <xsl:when test="$type = 7">
            <xsl:choose>
               <xsl:when test="value = 1">✓</xsl:when>
               <xsl:otherwise>—</xsl:otherwise>
            </xsl:choose>
         </xsl:when>
         <!-- Other types -->
         <xsl:otherwise>
            <xsl:value-of select="value"/>
         </xsl:otherwise>
      </xsl:choose>
      <xsl:if test="position() != last()">, </xsl:if>
   </xsl:template>

<!-- Шаблон, формирующий свойства -->
   <xsl:template match="property">
      <!-- Есть хотя бы одно значение свойства -->
      <xsl:variable name="property_id" select="@id" />
      <xsl:if test="count(/shop/comparing/shop_item/property_value[property_id=$property_id][not(file/node()) and value != '' or file != ''])">
         <tr>
            <th>
               <xsl:value-of select="name"/>
            </th>
            <xsl:apply-templates select="/shop/comparing/shop_item" mode="property">
               <!-- Передаем через параметр ID свойства -->
               <xsl:with-param name="property_id" select="@id"/>
            </xsl:apply-templates>
         </tr>
      </xsl:if>
   </xsl:template>

   <!-- Шаблон, формирующий значения свойств -->
   <xsl:template match="shop_item" mode="property">
      <!-- Принимаем параметр - ID свойства -->
      <xsl:param name="property_id"/>
      <td class="compare{@id}">
         <xsl:choose>
            <xsl:when test="count(property_value[property_id=$property_id])">
               <xsl:apply-templates select="property_value[property_id=$property_id]" />
            </xsl:when>
            <xsl:otherwise>—</xsl:otherwise>
         </xsl:choose>
      </td>
   </xsl:template>

   <!-- Шаблон вывода значений свойств -->
   <xsl:template match="property_value">
      <xsl:choose>
         <xsl:when test="not(file)">
            <xsl:value-of disable-output-escaping="yes" select="value"/>
         </xsl:when>
         <xsl:when test="file/node()">
            <a target="_blank" href="{../dir}{file}"><xsl:value-of select="file_name"/></a>
         </xsl:when>
      </xsl:choose>
      <xsl:if test="position() != last()">, </xsl:if>
   </xsl:template>