Как реализовать всплывающее меню?

<?xml version="1.0" encoding="utf-8"?>
<!DOCTYPE xsl:stylesheet>
<xsl:stylesheet version="1.0"
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   xmlns:hostcms="http://www.hostcms.ru/"
   exclude-result-prefixes="hostcms">
   <xsl:output xmlns="http://www.w3.org/TR/xhtml1/strict" doctype-public="-//W3C//DTD XHTML 1.0 Strict//EN" encoding="utf-8" indent="yes" method="html" omit-xml-declaration="no" version="1.0" media-type="text/xml"/>
   
   <xsl:template match="/site">
      <ul class="sf-menu">
         <!-- Выбираем узлы структуры первого уровня -->
         <xsl:apply-templates select="structure[show=1]" />
      </ul>
   </xsl:template>
   
   <!-- Запишем в константу ID структуры, данные для которой будут выводиться пользователю -->
   <xsl:variable name="current_structure_id" select="/site/current_structure_id"/>
   
   <xsl:template match="structure">
      <li>
         <!--
         Выделяем текущую страницу добавлением к li класса current,
         если это текущая страница, либо у нее есть ребенок с атрибутом id, равным текущей группе.
         -->
         <xsl:if test="$current_structure_id = @id or count(.//structure[@id=$current_structure_id]) = 1">
            <xsl:attribute name="class">current</xsl:attribute>
         </xsl:if>
         
         <!-- Определяем адрес ссылки -->
         <xsl:variable name="link">
            <xsl:choose>
               <!-- Если внешняя ссылка -->
               <xsl:when test="url != ''">
                  <xsl:value-of disable-output-escaping="yes" select="url"/>
               </xsl:when>
               <!-- Иначе если внутренняя ссылка -->
               <xsl:otherwise>
                  <xsl:value-of disable-output-escaping="yes" select="link"/>
               </xsl:otherwise>
            </xsl:choose>
         </xsl:variable>
         
         
         <!-- Определяем стиль вывода элемента в меню -->
         <xsl:variable name="a_style">
            <xsl:choose>
               <!-- Выделяем текущий пункт меню (если это текущая страница, либо у нее есть ребенок с ID, равным текущей) -->
               <xsl:when test="$current_structure_id=@id or count(.//structure[@id=$current_structure_id])=1">current</xsl:when>
               <!-- Иначе обычный вывод с неактивным стилем -->
               <xsl:otherwise>passive</xsl:otherwise>
            </xsl:choose>
         </xsl:variable>
         
         
         <!-- Ссылка на пункт меню -->
         <a href="{$link}" title="{name}" class="{$a_style}"><xsl:value-of disable-output-escaping="yes" select="name"/></a>
         <xsl:if test="count(structure[show=1]) > 0">
            <ul>
               <xsl:apply-templates select="structure" mode="sub" />
            </ul>
         </xsl:if>
      </li>
   </xsl:template>
   <xsl:template match="structure" mode="sub">
      <li>
         <a href="{link}" title="{name}">
            <xsl:value-of disable-output-escaping="yes" select="name"/>
         </a>
         <xsl:if test="count(structure[show=1]) > 0">
            <ul>
               <xsl:apply-templates select="structure" mode="sub" />
            </ul>
         </xsl:if>
      </li>
   </xsl:template>
</xsl:stylesheet>