adm.dream писал(а):
этой ветке говорилось о том что все можно взять на демо сайте а я там ничего подобного ненашел
- это потому что раньше у демо-сайта был другой макет, и на нам стандартно было реализовано выпадающее меню. Ниже приведен код XSL-шаблона, реализующего то выпадающее меню узлов структуры сайта:
<?xml version="1.0" encoding="utf-8"?>
<!DOCTYPE xsl:stylesheet>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output xmlns="http://www.w3.org/TR/xhtml1/strict" doctype-public="-//W3C//DTD XHTML 1.0 Strict//EN" encoding="utf-8" indent="yes" method="html" omit-xml-declaration="no" version="1.0" media-type="text/xml"/>
<xsl:template match="/document">
<table width="100%" border="0" cellpadding="0" cellspacing="0" class="top_menu">
<tr align="center">
<!-- Выбираем узлы структуры -->
<xsl:apply-templates select="structure[show=1]"/>
<td style="padding-right: 15px;"></td>
</tr>
</table>
</xsl:template>
<xsl:template match="structure">
<!-- Запишем в константу ID структуры, данные для которой будут выводиться пользователю -->
<xsl:variable name="current_structure_id" select="/document/structure/current_structure_id"/>
<td></td>
<td>
<div class="item_menu_div" id="menu_id_{@id}" onmouseover="TopMenuOver('menu_id_{@id}', 'child_menu_id_{@id}');" onmouseout="TopMenuOut('menu_id_{@id}', 'child_menu_id_{@id}');">
<div class="tl"></div>
<div class="tr"></div>
<div class="bl"></div>
<div class="br"></div>
<!-- Показывать ссылку, или нет -->
<xsl:if test="show_link=1">
<!-- Определяем адрес ссылки -->
<xsl:variable name="link">
<xsl:choose>
<!-- Если внешняя ссылка -->
<xsl:when test="is_external_link=1">
<xsl:value-of disable-output-escaping="yes" select="external_link"/>
</xsl:when>
<!-- Иначе если внутренняя ссылка -->
<xsl:otherwise>
<xsl:value-of disable-output-escaping="yes" select="link"/>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<!-- Определяем стиль вывода ссылки -->
<xsl:variable name="link_style">
<xsl:choose>
<!-- Выделяем текущую страницу жирным (если это текущая страница, либо у нее есть ребенок с ID, равным текущей) -->
<xsl:when test="current_structure_id=@id or count(.//structure[@id=$current_structure_id])=1">font-weight: bold</xsl:when>
<!-- Иначе обычный вывод с пустым стилем -->
<xsl:otherwise></xsl:otherwise>
</xsl:choose>
</xsl:variable>
<a href="{$link}">
<xsl:value-of disable-output-escaping="yes" select="name"/>
</a>
</xsl:if>
<!-- Выводим подуровни меню -->
<xsl:if test="count(structure[show = 1]) > 0">
<div id="child_menu_id_{@id}" class="poll_down_menu_lev_1" align="left">
<div class="tl"></div>
<div class="t"></div>
<div class="tr"></div>
<div class="r"></div>
<div class="bl"></div>
<div class="b"></div>
<div class="br"></div>
<div class="l"></div>
<ul>
<xsl:apply-templates select="structure[show=1]" mode="pool"/>
</ul>
</div>
</xsl:if>
<!-- Если не показывать ссылку - выводим просто имя ссылки -->
<xsl:if test="show_link=0">
<xsl:value-of disable-output-escaping="yes" select="name"/>
</xsl:if>
</div>
</td>
</xsl:template>
<xsl:template match="structure" mode="pool">
<li>
<!-- Показывать ссылку, или нет -->
<xsl:if test="show_link=1">
<!-- Определяем адрес ссылки -->
<xsl:variable name="link">
<xsl:choose>
<!-- Если внешняя ссылка -->
<xsl:when test="is_external_link=1">
<xsl:value-of disable-output-escaping="yes" select="external_link"/>
</xsl:when>
<!-- Иначе если внутренняя ссылка -->
<xsl:otherwise>
<xsl:value-of disable-output-escaping="yes" select="link"/>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<a href="{$link}">
<xsl:value-of disable-output-escaping="yes" select="name"/>
</a>
</xsl:if>
<!-- Если не показывать ссылку - выводим просто имя ссылки -->
<xsl:if test="show_link=0">
<xsl:value-of disable-output-escaping="yes" select="name"/>
</xsl:if>
</li>
</xsl:template>
</xsl:stylesheet>
Для корректности его работы и отображения необходимо подключить в коде макета файл /templates/template1/hostcms.js, а также добавить в CSS макета блок стилей:
.top_menu
{
margin-bottom: 30px;
}
.top_menu .item_menu_div
{
position: relative;
background: url('/images/fon_top_menu.gif') repeat-x 0 0;
background-color: #e85200;
height: 29px;
padding: 9px 15px 0px 15px;
white-space: nowrap;
z-index: 1;
}
.top_menu a
{
color: #FFF;
}
.top_menu td
{
padding-left: 15px;
}
.top_menu .poll_down_menu_lev_1
{
position: absolute;
display: none;
background-color: #d62d00;
padding: 5px 10px 5px 10px;
left: 8px;
top: 47px;
}
.top_menu .poll_down_menu_lev_1 ul
{
list-style-type: none;
padding: 0px;
margin: 3px 5px 0px 0px;
/*
opacity: 0.4;
filter: progid:DXImageTransform.Microsoft.Alpha(opacity=50);
*/
}
.top_menu .poll_down_menu_lev_1 li
{
margin-bottom: 3px;
padding-left: 16px;
background: url('/images/li_arr.gif') no-repeat 0 9px;
}